PSeInt: solicitar nombres de estudiantes y notas - Ejercicio resuelto

Hoy vamos a ver un ejercicio de programación con PSeInt que va a solicitar datos del alumno, notas del mismo y mostrar promedios así como los aprobados y reprobados.

Vamos a trabajar con arreglos y ciclos. El ejercicio dice así:

Un docente desea guardar las notas de sus estudiantes. Escriba un programa que le permita almacenar el nombre del estudiante y sus tres notas, obteniendo el promedio de las tres notas.

La salida deberá mostrar:

• Cantidad de estudiantes registrados
• Nombre del estudiante
• Nota 1
• Nota 2
• Nota 3
• Nota promedio
• Número de estudiantes aprobados
• Número de estudiantes reprobados

Código en PSeInt

Pasemos al código fuente de este ejercicio con PSeInt que queda así:

Algoritmo sin_titulo
	Dimension nombres_estudiantes[200];
	Dimension notas_1[200];
	Dimension notas_2[200];
	Dimension notas_3[200];
	aprobatoria <- 70
	aprobados <- 0
	reprobados <- 0
	Escribir "Ingrese la cantidad de estudiantes: ";
	Leer cantidad_elementos;
	// Leer datos
	Para i<-1 Hasta cantidad_elementos Hacer
		Escribir "Ingrese el nombre del estudiante ",i,": "
		Leer nombres_estudiantes[i];
		Escribir "Ingrese la nota #1 de ",nombres_estudiantes[i],": "
		Leer notas_1[i];
		Escribir "Ingrese la nota #2 de ",nombres_estudiantes[i],": "
		Leer notas_2[i];
		Escribir "Ingrese la nota #3 de ",nombres_estudiantes[i],": "
		Leer notas_3[i];
	FinPara
	
	Escribir "Estudiantes: ", cantidad_elementos;
	Para i<-1 Hasta cantidad_elementos Hacer
		Escribir "______________________________________";
		Escribir "Estudiante: ", nombres_estudiantes[i];
		Escribir "Nota 1: ", notas_1[i];
		Escribir "Nota 2: ", notas_2[i];
		Escribir "Nota 3: ", notas_3[i];
		nota_promedio <- (notas_1[i]+notas_2[i]+notas_3[i])/3;
		Escribir "Nota promedio: ", nota_promedio;
		Si nota_promedio >= aprobatoria Entonces
			aprobados = aprobados + 1
		SiNo
			reprobados = reprobados + 1
		FinSi;
		Escribir "______________________________________";
	FinPara
	Escribir "Aprobados: ", aprobados;
	Escribir "Reprobados: ", reprobados;
FinAlgoritmo

La ejecución se ve así:

Obviamente podemos cambiar la cantidad de alumnos. Yo lo hice así porque no quise que la ventana se hiciera muy grande.

Por aquí te dejo más posts de PSeInt.