Hace algún tiempo vimos cómo simular un semáforo con 3 leds en Arduino, en donde usamos delay. En este post veremos exactamente lo mismo, pero con una condición: no usar delay.

El enfoque que hoy veremos servirá para otros proyectos en donde no podemos usar delay, por ejemplo, en uno en donde debemos escuchar el botón presionado de un teclado pero además debemos usar el tiempo de alguna manera (en un cronómetro por poner una referencia).

Semáforo sin delay: un enfoque distinto

Para no usar delay usamos el tiempo, sí, el tiempo en milisegundos que ha transcurrido desde que encendimos el Arduino.

El enfoque es sencillo, en lugar de dormir y pausar toda la ejecución, miramos el tiempo.

Voy a poner un ejemplo sencillo:

Enciendo el led verde a las 8:00:00 (aunque en realidad en Arduino se obtienen los milisegundos desde que la placa se ha encendido) y guardo la hora de manera que diga “A las 8:00 encendí el verde”, dejo que el código se ejecute y  compruebo a cada momento (dentro del loop) la hora; cuando vea que son 8:00:05 entonces enciendo el led amarillo (apagando el verde), y guardo un registro de que a las 8:00:05 encendí el amarillo, dejo que el código se siga ejecutando y así infinitamente.

¿La ventaja? la ventaja es que podemos tener más código no bloqueante y podemos ejecutar distintas cosas sin necesidad de dormir o esperar.

Hablar es de mal gusto, muéstrame el código

Para obtener los milisegundos llamamos a la función millis, y almacenamos el resultado en una global llamada ultimosMilisegundos. Después de eso, dentro del loop comprobamos si ha pasado el tiempo suficiente como para cambiar de luz del semáforo.

Por cierto, este valor de milisegundos se va a resetear en unos días después de haber encendido la placa, pero no pasa nada, pues volverá a 0 ya que ocurrirá un desbordamiento de la variable; cosa nada grave si solo lo usamos para el tiempo transcurrido.

/*
  Prueba 1: Semáforo simple
  INSTRUCCIONES: Realizar un sketch en Arduino que permita
  encender tres LED’s con la lógica de funcionamiento de un
  semáforo simple. El proceso inicia con el encendido del VERDE.
  
  Extra: no usar delay
  @author parzibyte
  Visita: parzibyte.me/blog
*/unsigned long ultimosMilisegundos = 0,
              milisegundosActuales;

int ledRojo = 7,
    ledAmarillo = 8,
    ledVerde = 9,
    SEGUNDOS_DE_ESPERA_VERDE_Y_ROJO = 5 * 1000, // En mi caso puse que el verde y rojo duren 10 segundos (10,000 milisegundos)
    SEGUNDOS_DE_ESPERA_AMARILLO = 2 * 1000,      // En mi caso puse que el amarillo dure 2 segundos (2,000 milisegundos)
    LED_ACTUAL = 0; // Por defecto no hay led encendido

void setup() {
  /*
    Establecemos como salida los tres leds
  */  pinMode(ledRojo, OUTPUT);
  pinMode(ledAmarillo, OUTPUT);
  pinMode(ledVerde, OUTPUT);
}

void loop() {
  /*
    En el bucle simplemente llamamos a la función "semaforo"
  */  semaforo();
}

void semaforo() {
  milisegundosActuales = millis(); // Obtenemos los milisegundos actuales

  // Nos fijamos en cuál led está encendido...
  switch (LED_ACTUAL) {
    case 9:
      if (elTurnoDeVerdeORojoHaTerminado())
        cambiaA(ledAmarillo);
      break;
    case 8:
      if (elTurnoDeAmarilloHaTerminado())
        cambiaA(ledRojo);
      break;
    case 7:
      if (elTurnoDeVerdeORojoHaTerminado())
        cambiaA(ledVerde);
      break;

    // Por defecto encenderá el verde al inicio
    default:
      cambiaA(ledVerde);
      break;
  }
}

boolean elTurnoDeVerdeORojoHaTerminado() {
  /*
    Simple función que compara el tiempo que lleva encendido el led verde o rojo
    ya que ambos duran 10 segundos encendidos.
    Devuelve verdadero si ya estuvo encendido 10 segundos, falso en caso contrario
  */  if (milisegundosActuales - ultimosMilisegundos >= SEGUNDOS_DE_ESPERA_VERDE_Y_ROJO) {
    ultimosMilisegundos = milisegundosActuales;
    return true;
  }
  return false;
}

boolean elTurnoDeAmarilloHaTerminado() {
  /*
    Simple función que compara el tiempo que lleva encendido el led amarillo
    Devuelve verdadero si ya estuvo encendido 2 segundos, falso en caso contrario
  */  if (milisegundosActuales - ultimosMilisegundos >= SEGUNDOS_DE_ESPERA_AMARILLO) {
    ultimosMilisegundos = milisegundosActuales;
    return true;
  }
  return false;
}

void cambiaA(int nuevoLed) {
  /*
    Función ayudante que apaga el led y enciende el nuevo,
    además de asignar a LED_ACTUAL el valor del (valga la redundancia)
    led actual
  */  digitalWrite(LED_ACTUAL, LOW);
  LED_ACTUAL = nuevoLed;
  digitalWrite(LED_ACTUAL, HIGH);
}

Circuito del semáforo sin delay

Como solo cambiamos la lógica, el circuito queda intacto y es el mismo de la vez pasada:

Las resistencias son de 220 ohms.

Simular circuito

Si crees que no funciona, prueba el semáforo sin delay en este enlace.